nixgl flake input attempt

flake.nix

@@ -8,6 +8,10 @@
       inputs.nixpkgs.follows = "nixpkgs";
     };
     _1password-shell-plugins.url = "github:1Password/shell-plugins";
+    nixgl = {
+      url = "github:nix-community/nixGL";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
   };
 
   outputs = { self, nixpkgs, ... }@inputs:
@@ -16,52 +20,47 @@
       pkgs = nixpkgs.legacyPackages.${system};
       lib = pkgs.lib;
 
+      # These will get applied to both the configured user and the root user (if enabled)
       userOptions = config: {
         openssh.authorizedKeys.keyFiles = lib.optionals config.ssh [ ./personal_keys ];
-        extraGroups = lib.optionals config.root [ "wheel" ];
-        shell = lib.mkIf config.shell pkgs.zsh;
+        shell = lib.mkIf config.enableShell pkgs.zsh;
       };
 
-      homeManagerModules = config: [
-        self.homeManagerModules.default {
+      mkhomeManagerModules = config: [
+        self.homeManagerModules.default
+        # { inherit (config) extraImports; }
+        {
           user = config.user;
           stateVersion = config.stateVersion;
           profile = config.profile;
-          shell = config.shell;
+          enableShell = config.enableShell;
           ssh = config.ssh;
           _1password = config._1password;
+          docker = config.docker;
+          graphical = config.graphical;
+          steam = config.steam;
         }
       ] ++ config.extraImports;
 
     in
     {
-      homeManagerModules.default = { ... }: {
-        imports = [
-          ./nixosModules/options.nix
-          ./home.nix
-          inputs._1password-shell-plugins.hmModules.default
-        ];
-        nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
-          "1password-cli"
-        ];
-        
-        home.packages = with pkgs; [
-          (writeShellScriptBin "nhmu" ''
-            nix flake update --flake ~/.config/home-manager
-            nix run home-manager -- switch --flake ~/.config/home-manager
-          '')
-        ];
-      };
+      lib = { inherit mkhomeManagerModules; };
+
+      homeManagerModules.default = { ... }: { imports = [ ./homeManagerModules ]; };
 
       nixosModules.default = { config, ... }: {
         imports = [
-          ./nixosModules/options.nix
-          ./nixosModules/scripts.nix
+          ./nixosModules
           inputs.home-manager.nixosModules.default
         ];
         nix.settings.trusted-users = [ "root" "@wheel" ];
         users.users.${config.user} = {
           isNormalUser = true;
+          description = "John Lancaster";
+          extraGroups = []
+          ++ lib.optionals config.root [ "wheel" ]
+          ++ lib.optionals config.docker [ "docker" ]
+          ++ lib.optionals config.networking.networkmanager.enable [ "networkmanager" ];
         } // userOptions config;
 
         users.users.root = lib.mkIf config.root (userOptions config);
@@ -72,19 +71,24 @@
           extraConfig = "Defaults        timestamp_timeout=1440";
         };
 
-        programs.zsh.enable = lib.mkIf config.shell true;
+        programs.zsh.enable = lib.mkIf config.enableShell true;
+
+        virtualisation.docker = lib.mkIf config.docker {
+          enable = true;
+          enableOnBoot = true;
+          package = pkgs.docker;
+        };
 
         home-manager = {
           useUserPackages = true;
-          extraSpecialArgs = { inherit inputs; };
+          extraSpecialArgs = { inherit inputs; nixgl = inputs.nixgl; };
           users = {
             ${config.user} = {
-              imports = homeManagerModules config;
+              imports = mkhomeManagerModules config;
             };
           } // lib.optionalAttrs config.root {
             root = {
-              # home.stateVersion = config.stateVersion;
-              imports = homeManagerModules (config // { user = "root"; });
+              imports = mkhomeManagerModules (config // { user = "root"; });
             };
           };
         };

homeManagerModules/default.nix

@@ -1,12 +1,38 @@
-{ config, pkgs, lib, inputs, ... }:
-
+{ inputs, config, pkgs, lib, ... }:
 {
+  # These modules are each responsible for responding appropriately to the options
   imports = [
-    ./homeManagerModules/git.nix
-    ./homeManagerModules/shell.nix
-    ./homeManagerModules/ssh.nix
-    # inputs._1password-shell-plugins.hmModules.default
+    ./docker.nix
+    ./ghostty.nix
+    ./git.nix
+    ./shell.nix
+    ./ssh.nix
+    ./vscode.nix
+
+    ../nixosModules/options.nix
+    inputs._1password-shell-plugins.hmModules.default
   ];
+
+  nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
+    "1password-cli"
+    "discord"
+    "spotify"
+    "steam"
+    "steam-original"
+    "steam-unwrapped"
+    "steam-run"
+    "sublimetext4"
+    "vscode"
+    "vscode-extension-mhutchie-git-graph"
+    "vscode-extension-ms-vscode-remote-vscode-remote-extensionpack"
+    "vscode-extension-MS-python-vscode-pylance"
+    "vscode-extension-github-copilot"
+  ];
+
+  nixpkgs.config.permittedInsecurePackages = [
+    "openssl-1.1.1w"
+  ];
+
   # Home Manager needs a bit of information about you and the paths it should
   # manage.
   home.username = config.user;
@@ -26,11 +52,24 @@
     lazygit
     btop
     yazi
+    sops
+    (writeShellScriptBin "nhmu" ''
+      nix flake update --flake ~/.config/home-manager
+      nix run home-manager -- switch --flake ~/.config/home-manager --impure
+    '')
     # # It is sometimes useful to fine-tune packages, for example, by applying
     # # overrides. You can do that directly here, just don't forget the
     # # parentheses. Maybe you want to install Nerd Fonts with a limited number of
     # # fonts?
     # (pkgs.nerdfonts.override { fonts = [ "FantasqueSansMono" ]; })
+  ] ++ lib.optionals config.graphical [
+    discord
+    spotify
+    sublime4
+    joplin-desktop
+  ] ++ lib.optionals config._1password [
+    _1password-cli
+    gh  # GitHub CLI with 1Password integration
   ];
 
   # Home Manager can also manage your environment variables through
@@ -72,4 +111,4 @@
       vault = "Private"
     '';
   };
-}
+}

homeManagerModules/docker.nix

@@ -0,0 +1,11 @@
+{ config, lib, pkgs, ... }:
+{
+  home.packages = lib.mkIf config.docker (with pkgs; [
+    docker
+    docker-compose
+    lazydocker
+    (pkgs.writeShellScriptBin "test-docker" ''
+      echo "Hello from docker.nix!"
+    '')
+  ]);
+}

homeManagerModules/ghostty.nix

@@ -0,0 +1,115 @@
+{ config, pkgs, lib, nixgl, ... }:
+{
+  home.sessionVariables = lib.mkIf (config.enableShell && config.graphical) {
+    TERMINAL = "ghostty";
+  };
+  
+  # nixGL is now provided as a flake input
+  nixGL.packages = nixgl.packages.${pkgs.system};
+  nixGL.defaultWrapper = "mesa";
+  nixGL.installScripts = [ "mesa" ];
+
+  programs.ghostty = lib.mkIf (config.enableShell && config.graphical) {
+    enable = true;
+    enableZshIntegration = true;
+    package = config.lib.nixGL.wrap pkgs.ghostty;
+    settings = {
+      # command = "TERM=xterm-256color /usr/bin/bash";
+      font-size = 12;
+      font-family = "Source Code Pro";
+      # theme = "idleToes";
+      # theme = "CGA";
+      theme = "catppuccin-mocha";
+      # theme = "CobaltNext";
+      # clipboard-read = "allow";
+      copy-on-select = true;
+      shell-integration = "zsh";
+      shell-integration-features = [ "no-title" "sudo" ];
+      gtk-single-instance = true;
+
+      window-padding-balance = true ;
+      window-padding-x = 5;
+      window-padding-y = 5;
+      initial-window = true;
+      resize-overlay = "never";
+
+      # Example: https://gist.github.com/adibhanna/c552c452fb244b3b721e3c2432e85cde
+      keybind = [
+        "ctrl+s>n=new_split:down"
+        "ctrl+t>n=new_tab"
+        "ctrl+t>1=goto_tab:1"
+        "ctrl+t>2=goto_tab:2"
+        "ctrl+t>3=goto_tab:3"
+        "ctrl+s>i=goto_split:up"
+        "ctrl+s>k=goto_split:down"
+      ];
+
+      # window-position-x = 500;
+      # window-position-y = 500;
+      window-height = 40;
+      window-width = 200;
+    };
+  };
+
+  # https://github.com/ghostty-org/ghostty/discussions/3763#discussioncomment-11699970
+  xdg.desktopEntries."com.mitchellh.ghostty" = lib.mkIf (config.enableShell && config.graphical) {
+    name = "Ghostty";
+    type = "Application";
+    comment = "A terminal emulator";
+    exec = "ghostty";
+    icon = "com.mitchellh.ghostty";
+    terminal = false;
+    startupNotify = true;
+    categories = [ "System" "TerminalEmulator" ];
+    settings = {
+      Keywords = "terminal;tty;pty;";
+      X-GNOME-UsesNotifications = "true";
+      X-TerminalArgExec = "-e";
+      X-TerminalArgTitle = "--title=";
+      X-TerminalArgAppId = "--class=";
+      X-TerminalArgDir = "--working-directory=";
+      X-TerminalArgHold = "--wait-after-command";
+    };
+    actions = {
+      new-window = {
+        name = "New Window";
+        exec = "ghostty";
+      };
+    };
+  };
+
+  # https://discourse.nixos.org/t/apps-installed-via-home-manager-are-not-visible-within-gnome/48252/2
+  # home.activation.copyDesktopFiles = lib.hm.dag.entryAfter ["installPackages"] ''
+  #   if [ "$XDG_CURRENT_DESKTOP" = "GNOME" ]; then
+
+  #     mkdir -p "${config.home.homeDirectory}/.local/share/applications"
+
+  #     if [ -d "${config.home.homeDirectory}/.local/share/applications/nix" ]; then
+  #       rm -rf "${config.home.homeDirectory}/.local/share/applications/nix"
+  #     fi
+
+  #     ln -sf "${config.home.homeDirectory}/.nix-profile/share/applications" \
+  #       ${config.home.homeDirectory}/.local/share/applications/nix
+
+  #     mkdir -p "${config.home.homeDirectory}/.local/share/icons"
+
+  #     if [ -d "${config.home.homeDirectory}/.local/share/icons/nix" ]; then
+  #       rm -rf "${config.home.homeDirectory}/.local/share/icons/nix"
+  #     fi
+
+  #     ln -sf "${config.home.homeDirectory}/.nix-profile/share/icons" \
+  #       ${config.home.homeDirectory}/.local/share/icons/nix
+
+  #   fi
+  # '';
+
+  # https://wiki.nixos.org/wiki/GNOME
+  # https://hoverbear.org/blog/declarative-gnome-configuration-in-nixos/#setting-gnome-options
+  # dconf.settings = {
+  #   "org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom0" = {
+  #     "binding" = "<Super>Return";
+  #     "command" = "ghostty";
+  #     "name" = "Terminal";
+  #   };
+  # };
+}

homeManagerModules/shell.nix

@@ -6,7 +6,7 @@
       echo "Hello from ~/.config/home-manager/home.nix!"
     '')
   ];
-  programs.zsh = lib.mkIf config.shell {
+  programs.zsh = lib.mkIf config.enableShell {
     enable = true;
     enableCompletion = true;
     autosuggestion.enable = true;

homeManagerModules/vscode.nix

@@ -0,0 +1,19 @@
+{ config, lib, pkgs, ... }:
+{
+  programs.vscode = lib.mkIf config.graphical {
+    enable = true;
+    package = pkgs.vscode;
+    profiles.default.extensions = with pkgs.vscode-extensions; [
+      mhutchie.git-graph
+      ms-vscode-remote.vscode-remote-extensionpack
+      ms-python.python
+      ms-python.vscode-pylance
+      ms-toolsai.jupyter
+      charliermarsh.ruff
+      github.vscode-pull-request-github
+      github.vscode-github-actions
+      github.copilot
+      catppuccin.catppuccin-vsc
+    ];
+  };
+}

nixosModules/default.nix

@@ -0,0 +1,8 @@
+{ inputs, config, pkgs, lib, ... }:
+{
+  imports = [
+    ./options.nix
+    ./scripts.nix
+    ./steam.nix
+  ];
+}

nixosModules/options.nix

@@ -30,7 +30,7 @@
     description = "Whether enable all the root user stuff";
   };
 
-  options.shell = lib.mkOption {
+  options.enableShell = lib.mkOption {
     type = lib.types.bool;
     default = true;
     description = "Whether to enable all the zsh stuff";
@@ -53,4 +53,22 @@
     default = [];
     description = "Additional Home Manager modules to import";
   };
+
+  options.docker = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether to enable docker stuff";
+  };
+
+  options.graphical = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether this system has a graphical environment";
+  };
+
+  options.steam = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether this system has Steam installed";
+  };
 }

nixosModules/scripts.nix

@@ -5,12 +5,12 @@ in
 {
   environment.systemPackages = with pkgs; [
     (pkgs.writeShellScriptBin "nfs" ''
-        sudo nixos-rebuild switch --flake $(readlink -f /etc/nixos)#${hostName} --impure
+      sudo nixos-rebuild switch --flake $(readlink -f /etc/nixos)#${hostName} --impure
     '')
     (pkgs.writeShellScriptBin "nfsu" ''
-        FLAKE=$(readlink -f /etc/nixos)
-        nix flake update --flake $FLAKE --impure
-        sudo nixos-rebuild switch --flake $FLAKE#${hostName} --impure
+      FLAKE=$(readlink -f /etc/nixos)
+      nix flake update --flake $FLAKE --impure
+      sudo nixos-rebuild switch --flake $FLAKE#${hostName} --impure
     '')
   ];
 }

nixosModules/steam.nix

@@ -0,0 +1,10 @@
+{ config, pkgs, lib, ... }:
+{
+  programs.steam = lib.mkIf config.steam {
+    enable = true;
+    gamescopeSession.enable = true;
+    remotePlay.openFirewall = true; # Open ports in the firewall for Steam Remote Play
+    dedicatedServer.openFirewall = true; # Open ports in the firewall for Source Dedicated Server
+    localNetworkGameTransfers.openFirewall = true; # Open ports in the firewall for Steam Local Network Game Transfers
+  };
+}