updated module example

README.md

@@ -40,42 +40,52 @@ nhmu
 
 ```nix
 {
-  description = "Home Manager configuration of john";
+  description = "John's system flake";
 
   inputs = {
-    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
-    home-manager = {
+    jsl-home = {
-      url = "github:nix-community/home-manager";
+      url = "git+https://gitea.john-stream.com/john/jsl-home?ref=dev";
       inputs.nixpkgs.follows = "nixpkgs";
     };
-    john-home-config = {
-      url = "path:/home/john/home-manager";
-      inputs.nixpkgs.follows = "nixpkgs";
-      inputs.home-manager.follows = "home-manager";
-    };
   };
 
-  outputs =
+  outputs = { self, nixpkgs, ... }@inputs:
-    { nixpkgs, ... }@inputs:
+  let
-    let
+   system = "x86_64-linux";
-      system = "x86_64-linux";
+   nixosSystem = nixpkgs.lib.nixosSystem;
-      pkgs = nixpkgs.legacyPackages.${system};
+   hostName = "john-p14s";
-      homeManagerConfiguration = inputs.home-manager.lib.homeManagerConfiguration;
+  in
-      jslDefault = inputs.john-home-config.homeManagerModules.default;
+  {
-      userName = "john";
+    nixosConfigurations.${hostName} = nixosSystem {
-    in
+      specialArgs =
-    {
+      {
-      homeConfigurations."${userName}" = homeManagerConfiguration {
+        inherit inputs;
-        inherit pkgs;
+        inherit system;
-        modules = [
-          jslDefault {
-            user = "${userName}";
-            # Add any additional configuration here
-          }
-          ./home.nix
-          # Add other home manager modules here
-        ];
       };
+      modules = [
+        ./hardware-configuration.nix
+        ./configuration.nix
+        inputs.jsl-home.nixosModules.default
+        {
+          stateVersion = "24.05";
+          user = "john";
+          root = true;
+          ssh = true;
+          profile = "personal";
+          enableShell = true;
+          _1password = true;
+          docker = true;
+          graphical = true;
+          steam = true;
+          extraImports = [
+            ./home-manager/john.nix
+            ./home-manager/gnome.nix
+            ./home-manager/ssh.nix
+          ];
+        }
+      ];
     };
+  };
 }
 ```

flake.nix

@@ -2,53 +2,96 @@
   description = "Home Manager configuration flake for JSL";
 
   inputs = {
-    # Specify the source of Home Manager and Nixpkgs.
     nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
     home-manager = {
       url = "github:nix-community/home-manager";
       inputs.nixpkgs.follows = "nixpkgs";
     };
+    _1password-shell-plugins.url = "github:1Password/shell-plugins";
+    nixgl = {
+      url = "github:nix-community/nixGL";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
   };
 
-  outputs = { nixpkgs, home-manager, ... }:
+  outputs = { self, nixpkgs, ... }@inputs:
     let
       system = "x86_64-linux";
       pkgs = nixpkgs.legacyPackages.${system};
       lib = pkgs.lib;
 
-      homeManagerModule = { config, pkgs, ... }: {
+      # These will get applied to both the configured user and the root user (if enabled)
-        options.user = lib.mkOption {
+      userOptions = config: {
-          type = lib.types.str;
+        openssh.authorizedKeys.keyFiles = lib.optionals config.ssh [ ./personal_keys ];
-          description = "The username for the Home Manager configuration.";
+        shell = lib.mkIf config.enableShell pkgs.zsh;
-        };
-
-        options.profile = lib.mkOption {
-          type = lib.types.enum [ "personal" "work" ];
-          default = "personal";
-          description = "Profile type for the Home Manager configuration.";
-        };
-
-        imports = [ ./home.nix ];
       };
-      
+
-      # Function to create a home configuration for any user
+      mkhomeManagerModules = config: [
-      mkHomeConfiguration = username: home-manager.lib.homeManagerConfiguration {
+        self.homeManagerModules.default
-        inherit pkgs;
+        # { inherit (config) extraImports; }
-        modules = [ homeManagerModule { user = username; } ];
+        {
-      };
+          user = config.user;
-      
+          stateVersion = config.stateVersion;
-      # Default username from the module evaluation
+          profile = config.profile;
-      evaluatedOptions = lib.evalModules { modules = [ homeManagerModule ]; };
+          enableShell = config.enableShell;
-      userName = evaluatedOptions.config.user;
+          ssh = config.ssh;
+          _1password = config._1password;
+          docker = config.docker;
+          graphical = config.graphical;
+          steam = config.steam;
+        }
+      ] ++ config.extraImports;
+
     in
     {
-      # Default configuration using the default username
+      lib = { inherit mkhomeManagerModules; };
-      homeConfigurations.${userName} = mkHomeConfiguration userName;
-      
-      # Export the function so other flakes can create configurations for any user
-      lib.mkHomeConfiguration = mkHomeConfiguration;
 
-      # Export modules for reuse in other flakes
+      homeManagerModules.default = { ... }: { imports = [ ./homeManagerModules ]; };
-      homeManagerModules.default = homeManagerModule;
+
+      nixosModules.default = { config, ... }: {
+        imports = [
+          ./nixosModules
+          inputs.home-manager.nixosModules.default
+        ];
+        nix.settings.trusted-users = [ "root" "@wheel" ];
+        users.users.${config.user} = {
+          isNormalUser = true;
+          description = "John Lancaster";
+          extraGroups = []
+          ++ lib.optionals config.root [ "wheel" ]
+          ++ lib.optionals config.docker [ "docker" ]
+          ++ lib.optionals config.networking.networkmanager.enable [ "networkmanager" ];
+        } // userOptions config;
+
+        users.users.root = lib.mkIf config.root (userOptions config);
+        security.sudo-rs = lib.mkIf config.root {
+          enable = true;
+          execWheelOnly = false;
+          wheelNeedsPassword = false;
+          extraConfig = "Defaults        timestamp_timeout=1440";
+        };
+
+        programs.zsh.enable = lib.mkIf config.enableShell true;
+
+        virtualisation.docker = lib.mkIf config.docker {
+          enable = true;
+          enableOnBoot = true;
+          package = pkgs.docker;
+        };
+
+        home-manager = {
+          useUserPackages = true;
+          extraSpecialArgs = { inherit inputs; nixgl = inputs.nixgl; };
+          users = {
+            ${config.user} = {
+              imports = mkhomeManagerModules config;
+            };
+          } // lib.optionalAttrs config.root {
+            root = {
+              imports = mkhomeManagerModules (config // { user = "root"; });
+            };
+          };
+        };
+      };
     };
 }

home.nix

@@ -1,85 +0,0 @@
-{ config, pkgs, ... }:
-
-{
-  # Home Manager needs a bit of information about you and the paths it should
-  # manage.
-  home.username = config.user;
-  home.homeDirectory = "/home/${config.user}";
-
-  # This value determines the Home Manager release that your configuration is
-  # compatible with. This helps avoid breakage when a new Home Manager release
-  # introduces backwards incompatible changes.
-  #
-  # You should not change this value, even if you update Home Manager. If you do
-  # want to update the value, then make sure to first check the Home Manager
-  # release notes.
-  home.stateVersion = "25.05"; # Please read the comment before changing.
-
-  # The home.packages option allows you to install Nix packages into your
-  # environment.
-  home.packages = with pkgs; [
-    # # Adds the 'hello' command to your environment. It prints a friendly
-    # # "Hello, world!" when run.
-    # pkgs.hello
-    uv
-    git
-    eza
-    (writeShellScriptBin "nhmu" ''
-      nix flake update --flake ~/.config/home-manager
-      nix run home-manager -- switch --flake ~/.config/home-manager
-    '')
-
-    # # It is sometimes useful to fine-tune packages, for example, by applying
-    # # overrides. You can do that directly here, just don't forget the
-    # # parentheses. Maybe you want to install Nerd Fonts with a limited number of
-    # # fonts?
-    # (pkgs.nerdfonts.override { fonts = [ "FantasqueSansMono" ]; })
-
-    # # You can also create simple shell scripts directly inside your
-    # # configuration. For example, this adds a command 'my-hello' to your
-    # # environment:
-    # (pkgs.writeShellScriptBin "my-hello" ''
-    #   echo "Hello, ${config.home.username}!"
-    # '')
-  ];
-
-  # Home Manager is pretty good at managing dotfiles. The primary way to manage
-  # plain files is through 'home.file'.
-  home.file = {
-    # # Building this configuration will create a copy of 'dotfiles/screenrc' in
-    # # the Nix store. Activating the configuration will then make '~/.screenrc' a
-    # # symlink to the Nix store copy.
-    # ".screenrc".source = dotfiles/screenrc;
-
-    # # You can also set the file content immediately.
-    # ".gradle/gradle.properties".text = ''
-    #   org.gradle.console=verbose
-    #   org.gradle.daemon.idletimeout=3600000
-    # '';
-  };
-
-  # Home Manager can also manage your environment variables through
-  # 'home.sessionVariables'. These will be explicitly sourced when using a
-  # shell provided by Home Manager. If you don't want to manage your shell
-  # through Home Manager then you have to manually source 'hm-session-vars.sh'
-  # located at either
-  #
-  #  ~/.nix-profile/etc/profile.d/hm-session-vars.sh
-  #
-  # or
-  #
-  #  ~/.local/state/nix/profiles/profile/etc/profile.d/hm-session-vars.sh
-  #
-  # or
-  #
-  #  /etc/profiles/per-user/john/etc/profile.d/hm-session-vars.sh
-  #
-  home.sessionVariables = {
-    # EDITOR = "emacs";
-  };
-
-  # Let Home Manager install and manage itself.
-  programs.home-manager.enable = true;
-
-  # programs.ssh.enable = true;
-}

homeManagerModules/default.nix

@@ -0,0 +1,114 @@
+{ inputs, config, pkgs, lib, ... }:
+{
+  # These modules are each responsible for responding appropriately to the options
+  imports = [
+    ./docker.nix
+    ./ghostty.nix
+    ./git.nix
+    ./shell.nix
+    ./ssh.nix
+    ./vscode.nix
+
+    ../nixosModules/options.nix
+    inputs._1password-shell-plugins.hmModules.default
+  ];
+
+  nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) [
+    "1password-cli"
+    "discord"
+    "spotify"
+    "steam"
+    "steam-original"
+    "steam-unwrapped"
+    "steam-run"
+    "sublimetext4"
+    "vscode"
+    "vscode-extension-mhutchie-git-graph"
+    "vscode-extension-ms-vscode-remote-vscode-remote-extensionpack"
+    "vscode-extension-MS-python-vscode-pylance"
+    "vscode-extension-github-copilot"
+  ];
+
+  nixpkgs.config.permittedInsecurePackages = [
+    "openssl-1.1.1w"
+  ];
+
+  # Home Manager needs a bit of information about you and the paths it should
+  # manage.
+  home.username = config.user;
+  home.homeDirectory = lib.mkIf (config.user != "root") "/home/${config.user}";
+  home.stateVersion = config.stateVersion;
+
+  # The home.packages option allows you to install Nix packages into your
+  # environment.
+  home.packages = with pkgs; [
+    wget
+    curl
+    cacert
+    busybox
+    gnugrep
+    dig
+    gdu
+    lazygit
+    btop
+    yazi
+    sops
+    (writeShellScriptBin "nhmu" ''
+      nix flake update --flake ~/.config/home-manager
+      nix run home-manager -- switch --flake ~/.config/home-manager --impure
+    '')
+    # # It is sometimes useful to fine-tune packages, for example, by applying
+    # # overrides. You can do that directly here, just don't forget the
+    # # parentheses. Maybe you want to install Nerd Fonts with a limited number of
+    # # fonts?
+    # (pkgs.nerdfonts.override { fonts = [ "FantasqueSansMono" ]; })
+  ] ++ lib.optionals config.graphical [
+    discord
+    spotify
+    sublime4
+    joplin-desktop
+  ] ++ lib.optionals config._1password [
+    _1password-cli
+    gh  # GitHub CLI with 1Password integration
+  ];
+
+  # Home Manager can also manage your environment variables through
+  # 'home.sessionVariables'. These will be explicitly sourced when using a
+  # shell provided by Home Manager. If you don't want to manage your shell
+  # through Home Manager then you have to manually source 'hm-session-vars.sh'
+  # located at either
+  #
+  #  ~/.nix-profile/etc/profile.d/hm-session-vars.sh
+  #
+  # or
+  #
+  #  ~/.local/state/nix/profiles/profile/etc/profile.d/hm-session-vars.sh
+  #
+  # or
+  #
+  #  /etc/profiles/per-user/john/etc/profile.d/hm-session-vars.sh
+  #
+  home.sessionVariables = {
+    # EDITOR = "emacs";
+  };
+
+  # Let Home Manager install and manage itself.
+  programs.home-manager.enable = true;
+
+  # https://developer.1password.com/docs/cli/shell-plugins/nix/
+  programs._1password-shell-plugins = lib.mkIf config._1password {
+    # enable 1Password shell plugins for bash, zsh, and fish shell
+    enable = true;
+    # the specified packages as well as 1Password CLI will be
+    # automatically installed and configured to use shell plugins
+    # https://developer.1password.com/docs/cli/shell-plugins
+    plugins = with pkgs; [ gh ];
+  };
+  home.file.".config/1Password/ssh/agent.toml" = lib.mkIf config._1password {
+    # https://developer.1password.com/docs/ssh/agent/config
+    text = ''
+      [[ssh-keys]]
+      vault = "Private"
+    '';
+  };
+}

homeManagerModules/docker.nix

@@ -0,0 +1,11 @@
+{ config, lib, pkgs, ... }:
+{
+  home.packages = lib.mkIf config.docker (with pkgs; [
+    docker
+    docker-compose
+    lazydocker
+    (pkgs.writeShellScriptBin "test-docker" ''
+      echo "Hello from docker.nix!"
+    '')
+  ]);
+}

homeManagerModules/ghostty.nix

@@ -0,0 +1,115 @@
+{ config, pkgs, lib, nixgl, ... }:
+{
+  home.sessionVariables = lib.mkIf (config.enableShell && config.graphical) {
+    TERMINAL = "ghostty";
+  };
+  
+  # nixGL is now provided as a flake input
+  nixGL.packages = nixgl.packages.${pkgs.system};
+  nixGL.defaultWrapper = "mesa";
+  nixGL.installScripts = [ "mesa" ];
+
+  programs.ghostty = lib.mkIf (config.enableShell && config.graphical) {
+    enable = true;
+    enableZshIntegration = true;
+    package = config.lib.nixGL.wrap pkgs.ghostty;
+    settings = {
+      # command = "TERM=xterm-256color /usr/bin/bash";
+      font-size = 12;
+      font-family = "Source Code Pro";
+      # theme = "idleToes";
+      # theme = "CGA";
+      theme = "catppuccin-mocha";
+      # theme = "CobaltNext";
+      # clipboard-read = "allow";
+      copy-on-select = true;
+      shell-integration = "zsh";
+      shell-integration-features = [ "no-title" "sudo" ];
+      gtk-single-instance = true;
+
+      window-padding-balance = true ;
+      window-padding-x = 5;
+      window-padding-y = 5;
+      initial-window = true;
+      resize-overlay = "never";
+
+      # Example: https://gist.github.com/adibhanna/c552c452fb244b3b721e3c2432e85cde
+      keybind = [
+        "ctrl+s>n=new_split:down"
+        "ctrl+t>n=new_tab"
+        "ctrl+t>1=goto_tab:1"
+        "ctrl+t>2=goto_tab:2"
+        "ctrl+t>3=goto_tab:3"
+        "ctrl+s>i=goto_split:up"
+        "ctrl+s>k=goto_split:down"
+      ];
+
+      # window-position-x = 500;
+      # window-position-y = 500;
+      window-height = 40;
+      window-width = 200;
+    };
+  };
+
+  # https://github.com/ghostty-org/ghostty/discussions/3763#discussioncomment-11699970
+  xdg.desktopEntries."com.mitchellh.ghostty" = lib.mkIf (config.enableShell && config.graphical) {
+    name = "Ghostty";
+    type = "Application";
+    comment = "A terminal emulator";
+    exec = "ghostty";
+    icon = "com.mitchellh.ghostty";
+    terminal = false;
+    startupNotify = true;
+    categories = [ "System" "TerminalEmulator" ];
+    settings = {
+      Keywords = "terminal;tty;pty;";
+      X-GNOME-UsesNotifications = "true";
+      X-TerminalArgExec = "-e";
+      X-TerminalArgTitle = "--title=";
+      X-TerminalArgAppId = "--class=";
+      X-TerminalArgDir = "--working-directory=";
+      X-TerminalArgHold = "--wait-after-command";
+    };
+    actions = {
+      new-window = {
+        name = "New Window";
+        exec = "ghostty";
+      };
+    };
+  };
+
+  # https://discourse.nixos.org/t/apps-installed-via-home-manager-are-not-visible-within-gnome/48252/2
+  # home.activation.copyDesktopFiles = lib.hm.dag.entryAfter ["installPackages"] ''
+  #   if [ "$XDG_CURRENT_DESKTOP" = "GNOME" ]; then
+
+  #     mkdir -p "${config.home.homeDirectory}/.local/share/applications"
+
+  #     if [ -d "${config.home.homeDirectory}/.local/share/applications/nix" ]; then
+  #       rm -rf "${config.home.homeDirectory}/.local/share/applications/nix"
+  #     fi
+
+  #     ln -sf "${config.home.homeDirectory}/.nix-profile/share/applications" \
+  #       ${config.home.homeDirectory}/.local/share/applications/nix
+
+  #     mkdir -p "${config.home.homeDirectory}/.local/share/icons"
+
+  #     if [ -d "${config.home.homeDirectory}/.local/share/icons/nix" ]; then
+  #       rm -rf "${config.home.homeDirectory}/.local/share/icons/nix"
+  #     fi
+
+  #     ln -sf "${config.home.homeDirectory}/.nix-profile/share/icons" \
+  #       ${config.home.homeDirectory}/.local/share/icons/nix
+
+  #   fi
+  # '';
+
+  # https://wiki.nixos.org/wiki/GNOME
+  # https://hoverbear.org/blog/declarative-gnome-configuration-in-nixos/#setting-gnome-options
+  # dconf.settings = {
+  #   "org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom0" = {
+  #     "binding" = "<Super>Return";
+  #     "command" = "ghostty";
+  #     "name" = "Terminal";
+  #   };
+  # };
+}

homeManagerModules/git.nix

@@ -0,0 +1,21 @@
+{ config, lib, ... }:
+{
+  programs.git = lib.mkMerge [
+    {
+      enable = true;
+      extraConfig = {
+        credential.helper = "store --file ~/.git-credentials";
+        init.defaultBranch = "main";
+        push.autoSetupRemote = true;
+      };
+    }
+    (lib.mkIf (config.profile == "personal") {
+      userName = "John Lancaster";
+      userEmail = "32917998+jsl12@users.noreply.github.com";
+    })
+    (lib.mkIf (config.profile == "work") {
+      userName = "John Lancaster";
+      userEmail = "john.lancaster@crowncastle.com";
+    })
+  ];
+}

homeManagerModules/shell.nix

@@ -0,0 +1,44 @@
+{ config, pkgs, lib, inputs, ... }:
+{
+  home.packages = with pkgs; [
+    eza
+    (writeShellScriptBin "test-pkgs" ''
+      echo "Hello from ~/.config/home-manager/home.nix!"
+    '')
+  ];
+  programs.zsh = lib.mkIf config.enableShell {
+    enable = true;
+    enableCompletion = true;
+    autosuggestion.enable = true;
+    # syntaxHighlighting.enable = true;
+    history = {
+      append = true;
+      ignoreAllDups = true;
+      ignorePatterns = [
+        "history"
+        "ls"
+        "eza"
+        "clear"
+      ];
+      save = 1000;
+      size = 1000;
+      share = true;
+    };
+    oh-my-zsh = {
+      enable = true;
+      # theme = "risto";
+      theme = "agnoster";
+      plugins = [
+        "sudo"
+        "dotenv"
+        "git"
+        "ssh"
+        "ssh-agent"
+      ] ++ lib.optional config._1password "1password";
+    };
+    shellAliases.ls = "${pkgs.eza}/bin/eza -lgos type --no-time";
+    initContent = lib.mkIf config._1password '' 
+      source ${config.home.homeDirectory}/.config/op/plugins.sh
+    '';
+  };
+}

homeManagerModules/ssh.nix

@@ -0,0 +1,32 @@
+{ config, lib, ... }:
+{
+  programs.ssh = lib.mkIf config.ssh {
+    enable = true;
+    extraConfig = ''
+      SetEnv TERM="xterm-256color"
+      ${lib.optionalString config._1password "IdentityAgent ~/.1password/agent.sock"}
+    '';
+    matchBlocks = lib.mkMerge [
+      (lib.mkIf (config.profile == "personal") {
+        "panoptes" = {
+          hostname = "192.168.1.107";
+          user = "panoptes";
+        };
+        "pve5070" = {
+          hostname = "192.168.1.130";
+          user = "root";
+        };
+        "nix-test" = {
+          hostname = "192.168.1.36";
+          user = "john";
+        };
+      })
+      (lib.mkIf (config.profile == "work") {
+        "ubuntu-nvidia" = {
+          hostname = "10.118.46.120";
+          user = "john";
+        };
+      })
+    ];
+  };
+}

homeManagerModules/vscode.nix

@@ -0,0 +1,19 @@
+{ config, lib, pkgs, ... }:
+{
+  programs.vscode = lib.mkIf config.graphical {
+    enable = true;
+    package = pkgs.vscode;
+    profiles.default.extensions = with pkgs.vscode-extensions; [
+      mhutchie.git-graph
+      ms-vscode-remote.vscode-remote-extensionpack
+      ms-python.python
+      ms-python.vscode-pylance
+      ms-toolsai.jupyter
+      charliermarsh.ruff
+      github.vscode-pull-request-github
+      github.vscode-github-actions
+      github.copilot
+      catppuccin.catppuccin-vsc
+    ];
+  };
+}

nixosModules/default.nix

@@ -0,0 +1,8 @@
+{ inputs, config, pkgs, lib, ... }:
+{
+  imports = [
+    ./options.nix
+    ./scripts.nix
+    ./steam.nix
+  ];
+}

nixosModules/options.nix

@@ -0,0 +1,74 @@
+{ lib, ... }:
+
+{
+  options.user = lib.mkOption {
+    type = lib.types.str;
+    description = "The username for the Home Manager configuration.";
+  };
+
+  # This value determines the Home Manager release that your configuration is
+  # compatible with. This helps avoid breakage when a new Home Manager release
+  # introduces backwards incompatible changes.
+  #
+  # You should not change this value, even if you update Home Manager. If you do
+  # want to update the value, then make sure to first check the Home Manager
+  # release notes.
+  options.stateVersion = lib.mkOption {
+    type = lib.types.str;
+    description = "The state version when the configuration was initially created";
+  };
+
+  options.profile = lib.mkOption {
+    type = lib.types.enum [ "personal" "work" ];
+    default = "personal";
+    description = "Profile type for the Home Manager configuration.";
+  };
+
+  options.root = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether enable all the root user stuff";
+  };
+
+  options.enableShell = lib.mkOption {
+    type = lib.types.bool;
+    default = true;
+    description = "Whether to enable all the zsh stuff";
+  };
+
+  options.ssh = lib.mkOption {
+    type = lib.types.bool;
+    default = true;
+    description = "Whether to enable SSH configuration";
+  };
+
+  options._1password = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether to enable 1 password stuff";
+  };
+
+  options.extraImports = lib.mkOption {
+    type = lib.types.listOf lib.types.anything;
+    default = [];
+    description = "Additional Home Manager modules to import";
+  };
+
+  options.docker = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether to enable docker stuff";
+  };
+
+  options.graphical = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether this system has a graphical environment";
+  };
+
+  options.steam = lib.mkOption {
+    type = lib.types.bool;
+    default = false;
+    description = "Whether this system has Steam installed";
+  };
+}

nixosModules/scripts.nix

@@ -0,0 +1,16 @@
+{ config, pkgs, ... }:
+let
+  hostName = config.networking.hostName;
+in
+{
+  environment.systemPackages = with pkgs; [
+    (pkgs.writeShellScriptBin "nfs" ''
+      sudo nixos-rebuild switch --flake $(readlink -f /etc/nixos)#${hostName} --impure
+    '')
+    (pkgs.writeShellScriptBin "nfsu" ''
+      FLAKE=$(readlink -f /etc/nixos)
+      nix flake update --flake $FLAKE --impure
+      sudo nixos-rebuild switch --flake $FLAKE#${hostName} --impure
+    '')
+  ];
+}

nixosModules/steam.nix

@@ -0,0 +1,10 @@
+{ config, pkgs, lib, ... }:
+{
+  programs.steam = lib.mkIf config.steam {
+    enable = true;
+    gamescopeSession.enable = true;
+    remotePlay.openFirewall = true; # Open ports in the firewall for Steam Remote Play
+    dedicatedServer.openFirewall = true; # Open ports in the firewall for Source Dedicated Server
+    localNetworkGameTransfers.openFirewall = true; # Open ports in the firewall for Steam Local Network Game Transfers
+  };
+}

personal_keys

@@ -0,0 +1,3 @@
+ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABgQDIaHS9CLiDc6T1tja0fBwwv5qc6iwuckWN6w8MNo5yiR8LPWyrfueowNJkL4HMqu6OEuggtdybGw1Do4sW5o+toHCyWfZf3khI1l15opPXuVpD4CWED+SpJiZ0wBgRaCaWhfxLI+s4JOhjOO2OjiClPX3HfxIHyTpRiR78lOMcIieHSnzrAV2MatYKf6lL2ckOsIPwxo/OVM+1ljjX+HLq9IxGUCpWOnF4nF1rq3gKL2JUh2KsrgrzE3NB7EFuqKm8F0tF2rG3JjSvlwox0h06drKD02lpZWXPOBRlcyFDpNXymmc2bpG0S2Bbj5g+pqNBB0jO0h3kzWvYYqrtU/ElObg1cXhyi0PFOhhptlbhbK0Ao8B+pAbSZ661nMT3jpRWLVbnJrRFnXXdjX08r5eseQ3k4CFpv+g64n7yg3IMo9f8gA9P/hOexR+qu5AQ1Ad/tvkp6pPXnR/zsUnbe4p2A9MaNJm4E1zxbs5VGlXynNikXwDL+spkrnjwdfUULTk= john@JOHN-PC
+ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIFn5ilhqaeDsOWSk7y29se2NvxGm8djlfL3RGLokj0q6 john@john-p14s
+ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABAQDHh9SBuxU2dOJHnpGZAE4cwe0fXcTBBAx+JmRsmIX+Tk8zooeM32vbNxxSXiZNpBGH5wzHNb534dWexGGG3sOaONmcL7SCoPIvaAdnIn5VsiznerLrzppSbx3Qn8eyF97WAGCcOcIUNmTIDDx1m6zG762WQnoaUEy0Ul5IR7ET5GQxP3p5Qwx8yqfixKDwarvV421sUIxYt9gee31jS9jcI3MFd6EL57hWle95Z8BGpR/Q7sXDBTZQWMZauh5NPwLMZS7k3bHgxXZ7WNOw/J/yts1ckBbvIFJSRNnMuWD0oGnDTL6aivGi+Eiswp0fpKzYGzquB3/wr3VU4G1JcMM5 JuiceSSH